第九章：用一个实时调度台，真正看懂 LiveView

defmodule CityWeb.DispatchLive.Index do
  use CityWeb, :live_view

  alias City.Dispatch

  @impl true
  def mount(_params, _session, socket) do
    scope = socket.assigns.current_scope
    topic = "org:#{scope.user.organization_id}:dispatches"

    if connected?(socket) do
      Phoenix.PubSub.subscribe(City.PubSub, topic)
    end

    {:ok,
     socket
     |> assign(:form, to_form(%{"title" => ""}, as: :dispatch))
     |> stream(:dispatches, Dispatch.list_dispatches(scope))}
  end

  @impl true
  def render(assigns) do
    ~H"""
    <Layouts.app flash={@flash} current_scope={@current_scope}>
      <section>
        <h1>实时调度台</h1>

        <.form for={@form} phx-submit="save">
          <.input field={@form[:title]} label="新事件标题" />
          <.button>登记事件</.button>
        </.form>

        <ul id="dispatches" phx-update="stream">
          <li :for={{dom_id, dispatch} <- @streams.dispatches} id={dom_id}>
            <strong>{dispatch.title}</strong>
            <span>{dispatch.status}</span>
          </li>
        </ul>
      </section>
    </Layouts.app>
    """
  end

  @impl true
  def handle_event("save", %{"dispatch" => params}, socket) do
    case Dispatch.create_dispatch(socket.assigns.current_scope, params) do
      {:ok, _dispatch} ->
        {:noreply, assign(socket, :form, to_form(%{"title" => ""}, as: :dispatch))}

      {:error, changeset} ->
        {:noreply, assign(socket, :form, to_form(changeset, as: :dispatch))}
    end
  end

  @impl true
  def handle_info({:dispatch_created, dispatch}, socket) do
    {:noreply, stream_insert(socket, :dispatches, dispatch, at: 0)}
  end
end